[FIXED] Building Java 11 Project using Gradle plus JavaFX and dependencies

Issue

I am trying to build my Java 11 project to have either an executable jar (FatJar, SuperJar, whatever its called) or an EXE or any form of runnable version even a batch file (Using Application). Everything I try I either get JavaFX is missing or my dependencies included the packages arent visible and it error's out.

Here is my build.gradle

plugins {
    id 'application'
    id 'java'
    id 'maven-publish'
    id 'org.openjfx.javafxplugin' version '0.0.8'
    id 'edu.sc.seis.launch4j' version '2.4.6'
    id 'org.beryx.jlink' version '2.12.0'
}

application {
    mainClassName = 'sassa.sassa.Main'
}


repositories {
    mavenLocal()
    maven {
        url = uri('https://jitpack.io')
    }

    maven {
        url = uri('https://repo.maven.apache.org/maven2')
    }
}

javafx {
    version = "11.0.2"
    modules = [ 'javafx.controls', 'javafx.fxml', 'javafx.graphics' ]
}

jlink {
    launcher {
        name = 'sassa'
    }
}

dependencies {
    implementation 'com.github.toolbox4minecraft:amidst:v4.4-beta1'
    implementation 'com.googlecode.json-simple:json-simple:1.1.1'
}

jar {
    manifest {
        attributes("Manifest-Version": "1.0",
                "Main-Class": "sassa.main.Main");
    }
}
compileJava {
    doFirst {
        println "CLASSPATH IS $classpath.asPath"
        options.compilerArgs = [
                '--module-path', classpath.asPath,
                '--add-modules', 'javafx.graphics',
                '--add-modules', 'javafx.controls',
                '--add-modules', 'javafx.fxml'
        ]
        classpath = files()
    }
}

task fatJar(type: Jar) {
    manifest.from jar.manifest
    classifier = 'all'
    from {
        configurations.runtime.collect { it.isDirectory() ? it : zipTree(it) }
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    } {
        exclude "META-INF/*.SF"
        exclude "META-INF/*.DSA"
        exclude "META-INF/*.RSA"
    }
    with jar
}

launch4j {
    mainClassName = 'sassa.main.Main'
    icon = "${projectDir}/src/main/resources/sassa/sassa.ico"
    jreMinVersion = '11'
    jreMaxVersion = '14'
    jdkPreference = 'preferJre'
    initialHeapSize = 128
    maxHeapSize = 512
    stayAlive = false
    bundledJre64Bit = true
    dontWrapJar = true
    bundledJrePath = 'jre'
}

group = 'sassa'
version = '0.5.0'
sourceCompatibility = '11'

publishing {
    publications {
        maven(MavenPublication) {
            from(components.java)
        }
    }
}

Also for the layout of the project it is on github (I was using maven before but figured Gradle might work better. (The maven code is still on github) https://github.com/Zodsmar/SeedSearcherStandaloneTool/tree/development

Literally I have tried everything and I just can't seem to get a buildable version to distribute...

Also I have read up about module.info files I do not have any I want to have a simple build.gradle that just includes everything I need to build an executable.

Solution

To anyone whoever comes across this and wants to know how I fixed it. I created a Gradle build task and then was able to build Jars, EXEs, Tar, and Zip this is the gradle:

plugins {
    id 'application'
    id 'java'
    id 'maven-publish'
    id 'org.openjfx.javafxplugin' version '0.0.8'
    id 'edu.sc.seis.launch4j' version '2.4.6'
}

dependencies {
    implementation 'com.googlecode.json-simple:json-simple:1.1.1'
    implementation ('com.github.KaptainWutax:BiomeUtils:master-SNAPSHOT') {
        transitive = false;
        changing = true;
    }
    implementation ('com.github.KaptainWutax:FeatureUtils:master-SNAPSHOT')
    {
        transitive = false;
        changing = true;
    }
    implementation ('com.github.KaptainWutax:SeedUtils:master-SNAPSHOT')
    {
        transitive = false;
        changing = true;
    }
}


group = 'sassa'
version = 'v0.6.0'
sourceCompatibility = '1.8'
String stringVersion = version

javafx {
    version = "11.0.2"
    modules = [ 'javafx.controls', 'javafx.fxml', 'javafx.graphics' ]
}

application {
    mainClassName = 'sassa.main.Main'
}
jar {
    manifest {
        attributes 'Main-Class': 'sassa.main.Main'
    }
    from {
        configurations.runtime.collect { it.isDirectory() ? it : zipTree(it) }
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
}

launch4j {
    mainClassName = 'sassa.main.Main'
    outfile = group + "-" + stringVersion + ".exe"
    icon = "${projectDir}/src/main/resources/sassa/sassa.ico"
}

repositories {
    mavenLocal()
    maven {
        url = uri('https://jitpack.io')
    }

    maven {
        url = uri('https://repo.maven.apache.org/maven2')
    }
}

task buildAll(type: GradleBuild) {
    tasks = ['jar', 'createExe', 'assemble']
}

publishing {
    publications {
        maven(MavenPublication) {
            from(components.java)
        }
    }
}

Answered By - Zodsmar